let
  pins = import ./npins;
in {
  pkgs ? let
    rawPkgs = import pins.nixpkgs { };
    patchedNixpkgs = rawPkgs.applyPatches {
      name = "nixpkgs";
      src = pins.nixpkgs;
      patches = [
        (rawPkgs.fetchpatch {
          name = "python3Packages.django-simple-history: change to pyproject";
          url = "https://cl.forkos.org/changes/nixpkgs~203/revisions/1/patch?download";
          hash = "sha256-lR6hW+yJcmCyKafZU9c/XSUE1nwvjdq94I254lAZLTE=";
          decode = "base64 -d";
        })
        ./0001-django-htmx-init-at-1.19.0.patch
      ];
    };
  in import patchedNixpkgs { }
}: rec {
  shell = pkgs.mkShell {
    buildInputs = with pkgs; [
      npins
      gitFull
      pdm
      sqlite-interactive
      forkosIssueTracker
    ];
  };
  htmx = pkgs.fetchurl {
    url = "https://unpkg.com/browse/htmx.org@1.9.12/dist/htmx.min.js";
    hash = "sha256-ruX9vUDsKIabkzupk4YAyEbSEk37QyOHjNneN9eyc4g=";
  };
  forkosIssueTracker = pkgs.python3.pkgs.buildPythonApplication {
    pname = "forkosissuetracker";
    version = "0.1.0";
    pyproject = true;

    src = ./.;

    disabled = pkgs.python3.pkgs.pythonOlder "3.12";

    nativeBuildInputs = with pkgs.python3.pkgs; [ setuptools ];
    # nativeCheckInputs = with pkgs.python3.pkgs; [ pytestCheckHook ];

    propagatedBuildInputs = with pkgs.python3.pkgs; [
      django_4
      djangorestframework
      social-auth-core
      social-auth-app-django
      django-simple-history
      django-htmx
    ];

    installPhase = ''
      mkdir -p $out/opt/forkosissuetracker
      cp -r . $out/opt/forkosissuetracker
      chmod +x $out/opt/forkosissuetracker/forkosissuetracker/manage.py
      makeWrapper $out/opt/forkosissuetracker/forkosissuetracker/manage.py $out/bin/forkosissuetracker \
        --prefix PYTHONPATH : "$PYTHONPATH"
    '';


    # pythonImportsCheck = [ "" ];
  };
}