forked from lix-project/lix
A few notes: * The `echo hi` is needed to make sure that a file that can be read by `nix log` is properly created (i.e. some output is needed). This is known and to be fixed in #6051. * We explicitly ignore the floating-CA case here: the `$out` of `input3` depends on `$out` of `input2`. This means that there are actually two derivations - I assume that this is because at eval time (i.e. `nix-instantiate -A`) the hash of `input2` isn't known yet and the other .drv is created as soon as `input2` was built. This is another issue on its own, so we ignore the case here explicitly.
59 lines
1.5 KiB
Nix
59 lines
1.5 KiB
Nix
{ busybox }:
|
|
|
|
with import ./config.nix;
|
|
|
|
let
|
|
|
|
mkDerivation = args:
|
|
derivation ({
|
|
inherit system;
|
|
builder = busybox;
|
|
args = ["sh" "-e" args.builder or (builtins.toFile "builder-${args.name}.sh" "if [ -e .attrs.sh ]; then source .attrs.sh; fi; eval \"$buildCommand\"")];
|
|
outputHashMode = "recursive";
|
|
outputHashAlgo = "sha256";
|
|
} // removeAttrs args ["builder" "meta" "passthru"])
|
|
// { meta = args.meta or {}; passthru = args.passthru or {}; };
|
|
|
|
input1 = mkDerivation {
|
|
shell = busybox;
|
|
name = "build-remote-input-1";
|
|
buildCommand = "echo hi; echo FOO > $out";
|
|
requiredSystemFeatures = ["foo"];
|
|
outputHash = "sha256-FePFYIlMuycIXPZbWi7LGEiMmZSX9FMbaQenWBzm1Sc=";
|
|
};
|
|
|
|
input2 = mkDerivation {
|
|
shell = busybox;
|
|
name = "build-remote-input-2";
|
|
buildCommand = "echo hi; echo BAR > $out";
|
|
requiredSystemFeatures = ["bar"];
|
|
outputHash = "sha256-XArauVH91AVwP9hBBQNlkX9ccuPpSYx9o0zeIHb6e+Q=";
|
|
};
|
|
|
|
input3 = mkDerivation {
|
|
shell = busybox;
|
|
name = "build-remote-input-3";
|
|
buildCommand = ''
|
|
echo hi
|
|
read x < ${input2}
|
|
echo $x BAZ > $out
|
|
'';
|
|
requiredSystemFeatures = ["baz"];
|
|
outputHash = "sha256-daKAcPp/+BYMQsVi/YYMlCKoNAxCNDsaivwSHgQqD2s=";
|
|
};
|
|
|
|
in
|
|
|
|
mkDerivation {
|
|
shell = busybox;
|
|
name = "build-remote";
|
|
passthru = { inherit input1 input2 input3; };
|
|
buildCommand =
|
|
''
|
|
read x < ${input1}
|
|
read y < ${input3}
|
|
echo "$x $y" > $out
|
|
'';
|
|
outputHash = "sha256-5SxbkUw6xe2l9TE1uwCvTtTDysD1vhRor38OtDF0LqQ=";
|
|
}
|