forked from lix-project/lix
![Eelco Dolstra](/assets/img/avatar_default.png)
For several platforms we don't currently have "native" Nix packages (e.g. Mac OS X and FreeBSD). This provides the next best thing: a tarball containing the closure of Nix, plus a simple script "nix-finish-install" that initialises the Nix database, registers the paths in the closure as valid, and runs "nix-env -i /path/to/nix" to initialise the user profile. The tarball must be unpacked in the root directory. It creates /nix/store/... and /usr/bin/nix-finish-install. Typical installation is as follows: $ cd / $ tar xvf /path/to/nix-1.1pre1234_abcdef-x86_64-linux.tar.bz2 $ nix-finish-install (if necessary add ~/.nix-profile/etc/profile.d/nix.sh to the shell login scripts) After this, /usr/bin/nix-finish-install can be deleted, if desired. The downside to the binary tarball is that it's pretty big (~55 MiB for x86_64-linux).
228 lines
7.8 KiB
Nix
228 lines
7.8 KiB
Nix
{ nixpkgs ? <nixpkgs>
|
|
, nix ? { outPath = ./.; revCount = 1234; shortRev = "abcdef"; }
|
|
, officialRelease ? false
|
|
}:
|
|
|
|
let
|
|
|
|
jobs = rec {
|
|
|
|
|
|
tarball =
|
|
with import nixpkgs {};
|
|
|
|
releaseTools.sourceTarball {
|
|
name = "nix-tarball";
|
|
version = builtins.readFile ./version;
|
|
versionSuffix = if officialRelease then "" else "pre${toString nix.revCount}_${nix.shortRev}";
|
|
src = nix;
|
|
inherit officialRelease;
|
|
|
|
buildInputs =
|
|
[ curl bison25 flex2535 perl libxml2 libxslt w3m bzip2
|
|
tetex dblatex nukeReferences pkgconfig sqlite git
|
|
];
|
|
|
|
configureFlags = ''
|
|
--with-docbook-rng=${docbook5}/xml/rng/docbook
|
|
--with-docbook-xsl=${docbook5_xsl}/xml/xsl/docbook
|
|
--with-xml-flags=--nonet
|
|
--with-dbi=${perlPackages.DBI}/${perl.libPrefix}
|
|
--with-dbd-sqlite=${perlPackages.DBDSQLite}/${perl.libPrefix}
|
|
'';
|
|
|
|
postUnpack = ''
|
|
# Clean up when building from a working tree.
|
|
(cd $sourceRoot && (git ls-files -o | xargs -r rm -v))
|
|
'';
|
|
|
|
preConfigure = ''
|
|
# TeX needs a writable font cache.
|
|
export VARTEXFONTS=$TMPDIR/texfonts
|
|
'';
|
|
|
|
preDist = ''
|
|
make -C doc/manual install prefix=$out
|
|
|
|
make -C doc/manual manual.pdf prefix=$out
|
|
cp doc/manual/manual.pdf $out/manual.pdf
|
|
|
|
# The PDF containes filenames of included graphics (see
|
|
# http://www.tug.org/pipermail/pdftex/2007-August/007290.html).
|
|
# This causes a retained dependency on dblatex, which Hydra
|
|
# doesn't like (the output of the tarball job is distributed
|
|
# to Windows and Macs, so there should be no Linux binaries
|
|
# in the closure).
|
|
nuke-refs $out/manual.pdf
|
|
|
|
echo "doc manual $out/share/doc/nix/manual" >> $out/nix-support/hydra-build-products
|
|
echo "doc-pdf manual $out/manual.pdf" >> $out/nix-support/hydra-build-products
|
|
echo "doc release-notes $out/share/doc/nix/release-notes" >> $out/nix-support/hydra-build-products
|
|
'';
|
|
};
|
|
|
|
|
|
build =
|
|
{ system ? "x86_64-linux" }:
|
|
|
|
with import nixpkgs { inherit system; };
|
|
|
|
releaseTools.nixBuild {
|
|
name = "nix";
|
|
src = tarball;
|
|
|
|
buildInputs = [ curl perl bzip2 openssl pkgconfig sqlite boehmgc ];
|
|
|
|
configureFlags = ''
|
|
--disable-init-state
|
|
--with-dbi=${perlPackages.DBI}/${perl.libPrefix}
|
|
--with-dbd-sqlite=${perlPackages.DBDSQLite}/${perl.libPrefix}
|
|
--enable-gc
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
doInstallCheck = true;
|
|
};
|
|
|
|
binaryTarball =
|
|
{ system ? "x86_64-linux" }:
|
|
|
|
with import nixpkgs { inherit system; };
|
|
|
|
let
|
|
toplevel = build { inherit system; };
|
|
version = toplevel.src.version;
|
|
in
|
|
|
|
runCommand "nix-binary-tarball-${version}"
|
|
{ exportReferencesGraph = [ "closure" toplevel ];
|
|
buildInputs = [ perl ];
|
|
meta.description = "Distribution-independent Nix bootstrap binaries for ${system}";
|
|
}
|
|
''
|
|
storePaths=$(perl ${pathsFromGraph} ./closure)
|
|
printRegistration=1 perl ${pathsFromGraph} ./closure > $TMPDIR/reginfo
|
|
substitute ${./scripts/install-nix-from-closure.sh} $TMPDIR/install \
|
|
--subst-var-by nix ${toplevel} --subst-var-by regInfo /nix/store/reginfo
|
|
chmod +x $TMPDIR/install
|
|
fn=$out/nix-${version}-${system}.tar.bz2
|
|
mkdir -p $out/nix-support
|
|
echo "file binary-dist $fn" >> $out/nix-support/hydra-build-products
|
|
tar cvfj $fn \
|
|
--owner=root --group=root --absolute-names \
|
|
--transform "s,$TMPDIR/install,/usr/bin/nix-finish-install," \
|
|
--transform "s,$TMPDIR/reginfo,/nix/store/reginfo," \
|
|
$TMPDIR/install $TMPDIR/reginfo $storePaths
|
|
'';
|
|
|
|
|
|
coverage =
|
|
with import nixpkgs { system = "x86_64-linux"; };
|
|
|
|
releaseTools.coverageAnalysis {
|
|
name = "nix-build";
|
|
src = tarball;
|
|
|
|
buildInputs =
|
|
[ curl perl bzip2 openssl pkgconfig sqlite
|
|
# These are for "make check" only:
|
|
graphviz libxml2 libxslt
|
|
];
|
|
|
|
configureFlags = ''
|
|
--disable-init-state
|
|
--with-dbi=${perlPackages.DBI}/${perl.libPrefix}
|
|
--with-dbd-sqlite=${perlPackages.DBDSQLite}/${perl.libPrefix}
|
|
'';
|
|
|
|
dontInstall = false;
|
|
|
|
doInstallCheck = true;
|
|
|
|
lcovFilter = [ "*/boost/*" "*-tab.*" ];
|
|
|
|
# We call `dot', and even though we just use it to
|
|
# syntax-check generated dot files, it still requires some
|
|
# fonts. So provide those.
|
|
FONTCONFIG_FILE = texFunctions.fontsConf;
|
|
};
|
|
|
|
|
|
rpm_fedora13i386 = makeRPM_i686 (diskImageFuns: diskImageFuns.fedora13i386) 50;
|
|
rpm_fedora13x86_64 = makeRPM_x86_64 (diskImageFunsFun: diskImageFunsFun.fedora13x86_64) 50;
|
|
rpm_fedora16i386 = makeRPM_i686 (diskImageFuns: diskImageFuns.fedora16i386) 50;
|
|
rpm_fedora16x86_64 = makeRPM_x86_64 (diskImageFunsFun: diskImageFunsFun.fedora16x86_64) 50;
|
|
|
|
rpm_opensuse103i386 = makeRPM_i686 (diskImageFuns: diskImageFuns.opensuse103i386) 40;
|
|
rpm_opensuse110i386 = makeRPM_i686 (diskImageFuns: diskImageFuns.opensuse110i386) 50;
|
|
rpm_opensuse110x86_64 = makeRPM_x86_64 (diskImageFuns: diskImageFuns.opensuse110x86_64) 50;
|
|
|
|
|
|
deb_debian60i386 = makeDeb_i686 (diskImageFuns: diskImageFuns.debian60i386) 50;
|
|
deb_debian60x86_64 = makeDeb_x86_64 (diskImageFunsFun: diskImageFunsFun.debian60x86_64) 50;
|
|
|
|
deb_ubuntu1004i386 = makeDeb_i686 (diskImageFuns: diskImageFuns.ubuntu1004i386) 50;
|
|
deb_ubuntu1004x86_64 = makeDeb_x86_64 (diskImageFuns: diskImageFuns.ubuntu1004x86_64) 50;
|
|
deb_ubuntu1010i386 = makeDeb_i686 (diskImageFuns: diskImageFuns.ubuntu1010i386) 50;
|
|
deb_ubuntu1010x86_64 = makeDeb_x86_64 (diskImageFuns: diskImageFuns.ubuntu1010x86_64) 50;
|
|
deb_ubuntu1110i386 = makeDeb_i686 (diskImageFuns: diskImageFuns.ubuntu1110i386) 60;
|
|
deb_ubuntu1110x86_64 = makeDeb_x86_64 (diskImageFuns: diskImageFuns.ubuntu1110x86_64) 60;
|
|
deb_ubuntu1204i386 = makeDeb_i686 (diskImageFuns: diskImageFuns.ubuntu1204i386) 60;
|
|
deb_ubuntu1204x86_64 = makeDeb_x86_64 (diskImageFuns: diskImageFuns.ubuntu1204x86_64) 60;
|
|
|
|
|
|
# System tests.
|
|
tests.remote_builds = (import ./tests/remote-builds.nix rec {
|
|
nix = build { inherit system; }; system = "x86_64-linux";
|
|
}).test;
|
|
|
|
tests.nix_copy_closure = (import ./tests/nix-copy-closure.nix rec {
|
|
nix = build { inherit system; }; system = "x86_64-linux";
|
|
}).test;
|
|
|
|
};
|
|
|
|
|
|
makeRPM_i686 = makeRPM "i686-linux";
|
|
makeRPM_x86_64 = makeRPM "x86_64-linux";
|
|
|
|
makeRPM =
|
|
system: diskImageFun: prio:
|
|
|
|
with import nixpkgs { inherit system; };
|
|
|
|
releaseTools.rpmBuild rec {
|
|
name = "nix-rpm-${diskImage.name}";
|
|
src = jobs.tarball;
|
|
diskImage = (diskImageFun vmTools.diskImageFuns)
|
|
{ extraPackages = [ "perl-DBD-SQLite" "perl-devel" "sqlite" "sqlite-devel" "bzip2-devel" ]; };
|
|
memSize = 1024;
|
|
meta.schedulingPriority = prio;
|
|
postRPMInstall = "cd /tmp/rpmout/BUILD/nix-* && make installcheck";
|
|
};
|
|
|
|
|
|
makeDeb_i686 = makeDeb "i686-linux";
|
|
makeDeb_x86_64 = makeDeb "x86_64-linux";
|
|
|
|
makeDeb =
|
|
system: diskImageFun: prio:
|
|
|
|
with import nixpkgs { inherit system; };
|
|
|
|
releaseTools.debBuild {
|
|
name = "nix-deb";
|
|
src = jobs.tarball;
|
|
diskImage = (diskImageFun vmTools.diskImageFuns)
|
|
{ extraPackages = [ "libdbd-sqlite3-perl" "libsqlite3-dev" "libbz2-dev" ]; };
|
|
memSize = 1024;
|
|
meta.schedulingPriority = prio;
|
|
configureFlags = "--sysconfdir=/etc";
|
|
debRequires = [ "curl" "libdbd-sqlite3-perl" "libsqlite3-0" "libbz2-1.0" ];
|
|
doInstallCheck = true;
|
|
};
|
|
|
|
|
|
in jobs
|