forked from lix-project/lix
jade
0f99ed43f1
It seems like someone implemented precompiled headers a long time ago
and then it never got ported to meson or maybe didn't work at all.
This is, however, blessedly easy to simply implement. I went looking for
`#define` that could affect the result of precompiling the headers, and
as far as I can tell we aren't doing any of that, so this should truly
just be free build time savings.
Previous state:
Compilation (551 times):
Parsing (frontend): 1302.1 s
Codegen & opts (backend): 956.3 s
New state:
**** Time summary:
Compilation (567 times):
Parsing (frontend): 1123.0 s
Codegen & opts (backend): 1078.1 s
I wonder if the "regression" in codegen time is just doing the PCH
operation a few times, because meson does it per-target.
Change-Id: I664366b8069bab4851308b3a7571bea97ac64022
113 lines
3 KiB
Nix
113 lines
3 KiB
Nix
{
|
|
/**
|
|
Path to Lix's source, normally the flake's "self" argument
|
|
*/
|
|
self ? pkgs.lib.cleanSource ./.,
|
|
/**
|
|
Already instantiated Nixpkgs
|
|
*/
|
|
pkgs,
|
|
/**
|
|
pre-commit-hooks source path, normally from the flake input
|
|
*/
|
|
pre-commit-hooks,
|
|
}:
|
|
let
|
|
inherit (pkgs) lib;
|
|
# Import pre-commit bypassing the flake because flakes don't let
|
|
# you have overlays. Also their implementation forces an
|
|
# unnecessary reimport of nixpkgs for our use cases.
|
|
tools = import (pre-commit-hooks + "/nix/call-tools.nix") pkgs;
|
|
pre-commit-run = pkgs.callPackage (pre-commit-hooks + "/nix/run.nix") {
|
|
inherit tools;
|
|
isFlakes = true;
|
|
# unused!
|
|
gitignore-nix-src = builtins.throw "gitignore-nix-src is unused";
|
|
};
|
|
in
|
|
pre-commit-run {
|
|
src = self;
|
|
hooks = {
|
|
no-commit-to-branch = {
|
|
enable = true;
|
|
settings.branch = [ "main" ];
|
|
};
|
|
check-case-conflicts.enable = true;
|
|
check-executables-have-shebangs = {
|
|
enable = true;
|
|
stages = [ "commit" ];
|
|
};
|
|
check-shebang-scripts-are-executable = {
|
|
enable = true;
|
|
stages = [ "commit" ];
|
|
};
|
|
check-symlinks = {
|
|
enable = true;
|
|
excludes = [ "^tests/functional/lang/symlink-resolution/broken$" ];
|
|
};
|
|
check-merge-conflicts.enable = true;
|
|
end-of-file-fixer = {
|
|
enable = true;
|
|
excludes = [
|
|
"\\.drv$"
|
|
"^tests/functional/lang/"
|
|
];
|
|
};
|
|
mixed-line-endings = {
|
|
enable = true;
|
|
excludes = [ "^tests/functional/lang/" ];
|
|
};
|
|
release-notes = {
|
|
enable = true;
|
|
package = pkgs.build-release-notes;
|
|
files = ''^doc/manual/(change-authors\.yml|rl-next(-dev)?)'';
|
|
pass_filenames = false;
|
|
entry = ''
|
|
${lib.getExe pkgs.build-release-notes} --change-authors doc/manual/change-authors.yml doc/manual/rl-next doc/manual/rl-next-dev
|
|
'';
|
|
};
|
|
change-authors-sorted = {
|
|
enable = true;
|
|
package = pkgs.yq;
|
|
files = ''^doc/manual/change-authors\.yml'';
|
|
entry = "${pkgs.writeShellScript "change-authors-sorted" ''
|
|
set -euo pipefail
|
|
shopt -s inherit_errexit
|
|
|
|
echo "changes necessary to sort $1:"
|
|
diff -U3 <(${lib.getExe pkgs.yq} -y . "$1") <(${lib.getExe pkgs.yq} -Sy . "$1")
|
|
''}";
|
|
};
|
|
check-headers = {
|
|
enable = true;
|
|
package = pkgs.check-headers;
|
|
files = "^src/";
|
|
types = [
|
|
"c++"
|
|
"file"
|
|
"header"
|
|
];
|
|
excludes = [
|
|
''^src/pch/.*$''
|
|
# generated files; these will never actually be seen by this
|
|
# check, and are left here as documentation
|
|
''(parser|lexer)-tab\.hh$''
|
|
''\.gen\.hh$''
|
|
];
|
|
entry = lib.getExe pkgs.check-headers;
|
|
};
|
|
# TODO: Once the test suite is nicer, clean up and start
|
|
# enforcing trailing whitespace on tests that don't explicitly
|
|
# check for it.
|
|
trim-trailing-whitespace = {
|
|
enable = true;
|
|
stages = [ "commit" ];
|
|
excludes = [ "^tests/functional/lang/" ];
|
|
};
|
|
treefmt = {
|
|
enable = true;
|
|
settings.formatters = [ pkgs.nixfmt ];
|
|
};
|
|
};
|
|
}
|