infra/flake.nix

{
  description = "Bagel cooking infrastructure";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    terranix.url = "github:terranix/terranix";

    agenix.url = "github:ryantm/agenix";
    agenix.inputs.nixpkgs.follows = "nixpkgs";

    colmena.url = "github:zhaofengli/colmena";
    colmena.inputs.nixpkgs.follows = "nixpkgs";

    hydra.url = "git+https://git.lix.systems/lix-project/hydra.git";
    hydra.inputs.nixpkgs.follows = "nixpkgs";

    nix-gerrit.url = "git+https://git.lix.systems/the-distro/nix-gerrit.git";
    nix-gerrit.inputs.nixpkgs.follows = "nixpkgs";

    buildbot-nix.url = "git+https://git.lix.systems/lix-project/buildbot-nix.git?ref=refs/heads/refactor";
    buildbot-nix.inputs.nixpkgs.follows = "nixpkgs";

    lix.follows = "hydra/lix";
  };

  outputs = { self, nixpkgs, terranix, colmena, ... } @ inputs:
  let
    system = "x86_64-linux";
    pkgs = import nixpkgs {
      localSystem = system;
      overlays = [
        inputs.hydra.overlays.default
        inputs.lix.overlays.default
        inputs.nix-gerrit.overlays.default
      ];
    };
    lib = pkgs.lib;
    terraform = pkgs.opentofu;
    terraformCfg = terranix.lib.terranixConfiguration {
      inherit system;
      modules = [
        ./terraform
        {
          bagel.gandi.enable = true;
          bagel.hydra.enable = true;
        }
      ];
    };
  in
  {
    apps.${system} = {
      tf = {
        type = "app";
        program = toString (pkgs.writers.writeBash "tf" ''
            set -eo pipefail
            ln -snf ${terraformCfg} config.tf.json
            exec ${lib.getExe terraform} "$@"
          '');
      };

      default = self.apps.${system}.tf;
    };

    devShells.${system}.default = pkgs.mkShell {
      packages = [
        inputs.agenix.packages.${system}.agenix

        pkgs.colmena
        pkgs.opentofu
      ];
    };

    nixosConfigurations = (colmena.lib.makeHive self.outputs.colmena).nodes;

    colmena = let
      commonModules = [
        inputs.agenix.nixosModules.default
        inputs.hydra.nixosModules.hydra
        inputs.buildbot-nix.nixosModules.buildbot-coordinator
        inputs.buildbot-nix.nixosModules.buildbot-worker

        ./services
        ./common
      ];

      makeBuilder = i: lib.nameValuePair "builder-${toString i}" {
        imports = commonModules;
        bagel.baremetal.builders = { enable = true; num = i; };
      };

      builders = lib.listToAttrs (lib.genList makeBuilder 12);
    in {
      meta.nixpkgs = import nixpkgs {
        localSystem = system;
        overlays = [
          inputs.hydra.overlays.default
          inputs.lix.overlays.default
          inputs.nix-gerrit.overlays.default
        ];
      };
      meta.specialArgs.inputs = inputs;

      bagel-box.imports = commonModules ++ [ ./hosts/bagel-box ];
      meta01.imports = commonModules ++ [ ./hosts/meta01 ];
      gerrit01.imports = commonModules ++ [ ./hosts/gerrit01 ];
      fodwatch.imports = commonModules ++ [ ./hosts/fodwatch ];
      git.imports = commonModules ++ [ ./hosts/git ];
      wob-vpn-gw.imports = commonModules ++ [ ./hosts/wob-vpn-gw ];
    } // builders;

    hydraJobs = builtins.mapAttrs (n: v: v.config.system.build.toplevel) self.nixosConfigurations;
  };
}