forked from lix-project/lix
0dbd4638e0
intersectAttrs returns the (right-biased) intersection between two
attribute sets, e.g. every attribute from the second set that also
exists in the first. functionArgs returns the set of attributes
expected by a function.
The main goal of these is to allow the elimination of most of
all-packages.nix. Most package instantiations in all-packages.nix
have this form:
foo = import ./foo.nix {
inherit a b c;
};
With intersectAttrs and functionArgs, this can be written as:
foo = callPackage (import ./foo.nix) { };
where
callPackage = f: args:
f ((builtins.intersectAttrs (builtins.functionArgs f) pkgs) // args);
I.e., foo.nix is called with all attributes from "pkgs" that it
actually needs (e.g., pkgs.a, pkgs.b and pkgs.c). (callPackage can
do any other generic package-level stuff we might want, such as
applying makeOverridable.) Of course, the automatically supplied
arguments can be overriden if needed, e.g.
foo = callPackage (import ./foo.nix) {
c = c_version_2;
};
but for the vast majority of packages, this won't be needed.
The advantages are to reduce the amount of typing needed to add a
dependency (from three sites to two), and to reduce the number of
trivial commits to all-packages.nix. For the former, there have
been two previous attempts:
- Use "args: with args;" in the package's function definition.
This however obscures the actual expected arguments of a
function, which is very bad.
- Use "{ arg1, arg2, ... }:" in the package's function definition
(i.e. use the ellipis "..." to allow arbitrary additional
arguments), and then call the function with all of "pkgs" as an
argument. But this inhibits error detection if you call it with
an misspelled (or obsolete) argument.
80 lines
2.5 KiB
Nix
80 lines
2.5 KiB
Nix
let
|
|
|
|
stdenvFun = { }: { name = "stdenv"; };
|
|
stdenv2Fun = { }: { name = "stdenv2"; };
|
|
fetchurlFun = { stdenv }: assert stdenv.name == "stdenv"; { name = "fetchurl"; };
|
|
atermFun = { stdenv, fetchurl }: { name = "aterm-${stdenv.name}"; };
|
|
aterm2Fun = { stdenv, fetchurl }: { name = "aterm2-${stdenv.name}"; };
|
|
nixFun = { stdenv, fetchurl, aterm }: { name = "nix-${stdenv.name}-${aterm.name}"; };
|
|
|
|
mplayerFun =
|
|
{ stdenv, fetchurl, enableX11 ? false, xorg ? null, enableFoo ? true, foo ? null }:
|
|
assert stdenv.name == "stdenv2";
|
|
assert enableX11 -> xorg.libXv.name == "libXv";
|
|
assert enableFoo -> foo != null;
|
|
{ name = "mplayer-${stdenv.name}.${xorg.libXv.name}-${xorg.libX11.name}"; };
|
|
|
|
makeOverridable = f: origArgs: f origArgs //
|
|
{ override = newArgs:
|
|
makeOverridable f (origArgs // (if builtins.isFunction newArgs then newArgs origArgs else newArgs));
|
|
};
|
|
|
|
callPackage_ = pkgs: f: args:
|
|
makeOverridable f ((builtins.intersectAttrs (builtins.functionArgs f) pkgs) // args);
|
|
|
|
allPackages =
|
|
{ overrides ? (pkgs: pkgsPrev: { }) }:
|
|
let
|
|
callPackage = callPackage_ pkgs;
|
|
pkgs = pkgsStd // (overrides pkgs pkgsStd);
|
|
pkgsStd = {
|
|
inherit pkgs;
|
|
stdenv = callPackage stdenvFun { };
|
|
stdenv2 = callPackage stdenv2Fun { };
|
|
fetchurl = callPackage fetchurlFun { };
|
|
aterm = callPackage atermFun { };
|
|
xorg = callPackage xorgFun { };
|
|
mplayer = callPackage mplayerFun { stdenv = pkgs.stdenv2; enableFoo = false; };
|
|
nix = callPackage nixFun { };
|
|
};
|
|
in pkgs;
|
|
|
|
libX11Fun = { stdenv, fetchurl }: { name = "libX11"; };
|
|
libX11_2Fun = { stdenv, fetchurl }: { name = "libX11_2"; };
|
|
libXvFun = { stdenv, fetchurl, libX11 }: { name = "libXv"; };
|
|
|
|
xorgFun =
|
|
{ pkgs }:
|
|
let callPackage = callPackage_ (pkgs // pkgs.xorg); in
|
|
{
|
|
libX11 = callPackage libX11Fun { };
|
|
libXv = callPackage libXvFun { };
|
|
};
|
|
|
|
in
|
|
|
|
let
|
|
|
|
pkgs = allPackages { };
|
|
|
|
pkgs2 = allPackages {
|
|
overrides = pkgs: pkgsPrev: {
|
|
stdenv = pkgs.stdenv2;
|
|
nix = pkgsPrev.nix.override { aterm = aterm2Fun { inherit (pkgs) stdenv fetchurl; }; };
|
|
xorg = pkgsPrev.xorg // { libX11 = libX11_2Fun { inherit (pkgs) stdenv fetchurl; }; };
|
|
};
|
|
};
|
|
|
|
in
|
|
|
|
[ pkgs.stdenv.name
|
|
pkgs.fetchurl.name
|
|
pkgs.aterm.name
|
|
pkgs2.aterm.name
|
|
pkgs.xorg.libX11.name
|
|
pkgs.xorg.libXv.name
|
|
pkgs.mplayer.name
|
|
pkgs2.mplayer.name
|
|
pkgs.nix.name
|
|
pkgs2.nix.name
|
|
]
|